気の向くままに辿るIT/ICT/IoT
IoT・電子工作

Arduino/LCD1602/RTCでSleep/表示・バックライトON/OFF SW付き時計を作る

ホーム前へ次へ
Arduinoって?

Arduino/LCD1602/RTCでSleep/表示・バックライトON/OFF SW付き時計を作る

Arduino/LCD1602/RTCでSleep/表示・バックライトON/OFF SW付き時計を作る

画面表示・バックライトON/OFF・スリープ機能付きArduino/RTC DS1302/LCD 1602時計
2019/04/09

 Arduinoと液晶ディスプレイLCD1602を使ってPower-downモードによるスリープ、ウォッチドックタイマー(WDT)による復帰、物理的な液晶表示のON/OFF、バックライトのON/OFFスイッチ付きデジタル時計を自作してみるページ。

画面表示ON/バックライトOFF

 画面表示ON/バックライトOFF。

画面表示OFF/バックライトOFF

 画面表示OFF/バックライトOFF。

画面表示OFF/バックライトON

 画面表示OFF/バックライトON。

画面表示ON/バックライトON(失敗)

 画面表示ON/バックライトON...見えない...

画面表示ON/バックライトON

 これもピンぼけしてますが、画面表示ON/バックライトONの場合、実際はこんな感じです...。

 バックライト点けた場合、どうやったら、うまく撮影できるんでしょうか...。

 で、併せてArduinoで最もDeepなSleep、SLEEP_MODE_PWR_DOWNもしている、と。

今回使ったもの

 Arduinoボードは、Uno系なら何を使っても同じ方法でいけますし、miniUSBケーブルは100均にもあり、RTCモジュールはDS1307やDS3231/3232などでも、というか3択なら、ボタン電池CR2302を使う場合、パターンカットなど対処を要すものの、アラーム機能付きなど高機能で完成度が高くバグのないDS3231が推奨っぽい、スイッチは、ロッカスイッチでもトグルスイッチでも他でも可です。

 スリープ機能が働くのは、ICチップであってArduinoのような開発ボードは、他に電力を消費するものが搭載されているため、電力消費を激減させたい場合には、5V版ではなく、3.3V版、もっと言えば開発ボードではなく、ATMega328PなどのIC単体での実装が効果的です。

 検証回路としては、ザッとAmazon/Amazonマーケットプレイス相場でArduino Nano 300円前後、LCD1602+I2Cモジュールは、300円前後、DS1302は今や高めで300円前後(DS1307の方が150円前後と割安っぽく、最も推奨されるDS3231も300円前後)、ロッカスイッチは100円前後、ミニブレッドボードも100円前後、ジャンパワイヤ適量20円、ワニグチクリップケーブル20円x4=80円と仮定、CR2302は100均一で単価54円(2個108円)、USBケーブルは100均一で108円とすると1300円前後、Aliexpressでこの6〜8割程度といったところでしょうか。

 LCD1602/LCD2004などのキャラクタ液晶は、個別に買ってはんだ付けでも構いませんが、何れにしても配線4本で済むI2Cモジュール付きがなんと言っても楽で嵩張らず簡単です。

回路

ArduinoLCD1602
I2C
DS1302液晶SWBacklight SW備考
SDA(A4)SDA---
SCL(A5)SCL--
4---他極はGNDへ
5---
6-CLK--
7DAT
8RST
5VVCC
GND

 表のスペース節約を図った結果、スイッチをSW、バックライトをBacklightと表記しました。

 スイッチの接続は少し悩んだ結果○印にしました。

 尚、表示とバックライトのON/OFFスイッチありきで考えたため、後述のスケッチのウォッチドックタイマー4秒との兼ね合いで切り替えから、若干タイムラグが生じます。

 むしろ、タイムラグはありますが、スリープ・復帰とこれらのON/OFFスイッチを併用できます、というか、そうしたくて結果、こうなりました。

 電源は、ArduinoボードをUSB接続するか、電池なら+/-をVIN/GNDに接続します。

 電池の場合、GNDは他とは別のピンからとります。

スケッチ・ライブラリ

#include <LiquidCrystal_PCF8574.h>
#include <MyRealTimeClock.h>
#include <avr/sleep.h>                  // スリープライブラリ
#include <avr/wdt.h>                    // ウォッチドッグタイマー ライブラリ
 
LiquidCrystal_PCF8574 lcd(0x27); // lcd1602 yellow black
//LiquidCrystal_PCF8574 lcd(0x3F); // lcd2004 yellow black
 
MyRealTimeClock myRTC(6, 7, 8);
 
char daysOfTheWeek[7][12] = {"Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat"};
 
const int dsw = 4; // Display ON/OFF Switch
const int bsw = 5; // Backlight ON/OFF Switch
 
volatile int wdt_cycle = 0;           // 必要ならコメントアウトを削除
// 0=16ms, 1=32ms, 2=64ms, 3=128ms, 4=250ms, 5=500ms
// 6=1sec, 7=2sec, 8=4sec, 9=8sec
int wdt_time_num = 8;
// 60sec/4sec=15
int const_num = 15;
 
void setup() {
  Serial.begin(9600);
  pinMode(dsw, INPUT_PULLUP);
  pinMode(bsw, INPUT_PULLUP);
//  myRTC.setDS1302Time(00, 15, 10, 0 , 07, 04, 2019);
  lcd.begin(16, 2);
  lcd.print("DS1302 Clock");
  Serial.println("DS1302 Clock");
  lcd.setCursor(0,1);
  lcd.print("Start ...");
  Serial.println("Start ...");
  delay(2000);
  clockDisp();
}
 
void loop() {
  sw_trig();
  // delayWDT2(8):4sec*15=60sec
  if (wdt_cycle == const_num) {
    clockDisp();
    wdt_cycle = 0;
  }
  delayWDT2(wdt_time_num);
}
 
void delayWDT2(unsigned long t) {       // パワーダウンモードでdelayを実行
  Serial.flush();                       // シリアルバッファが空になるまで待つ
  delayWDT_setup(t);                    // ウォッチドッグタイマー割り込み条件設定
 
  // ADCを停止(消費電流 147→27μA)
  ADCSRA &= ~(1 << ADEN);
 
  set_sleep_mode(SLEEP_MODE_PWR_DOWN);  // パワーダウンモード指定
  sleep_enable();
 
  // BODを停止(消費電流 27→6.5μA)
  MCUCR |= (1 << BODSE) | (1 << BODS);   // MCUCRのBODSとBODSEに1をセット
  MCUCR = (MCUCR & ~(1 << BODSE)) | (1 << BODS);  // すぐに(4クロック以内)BODSSEを0, BODSを1に設定
 
  asm("sleep");                         // 3クロック以内にスリープ sleep_mode();では間に合わなかった
 
  sleep_disable();                      // WDTがタイムアップでここから動作再開
  ADCSRA |= (1 << ADEN);                // ADCの電源をON(BODはハードウエアで自動再開される)
}
 
void delayWDT_setup(unsigned int ii) {  // ウォッチドッグタイマーをセット。
  // 引数はWDTCSRにセットするWDP0-WDP3の値。設定値と動作時間は概略下記
  // 0=16ms, 1=32ms, 2=64ms, 3=128ms, 4=250ms, 5=500ms
  // 6=1sec, 7=2sec, 8=4sec, 9=8sec
  byte bb;
  if (ii > 9 ) {                        // 変な値を排除
    ii = 9;
  }
  bb = ii & 7;                          // 下位3ビットをbbに
  if (ii > 7) {                         // 7以上(7.8,9)なら
    bb |= (1 << 5);                     // bbの5ビット目(WDP3)を1にする
  }
  bb |= ( 1 << WDCE );
 
  MCUSR &= ~(1 << WDRF);                // MCU Status Reg. Watchdog Reset Flag ->0
  // start timed sequence
  WDTCSR |= (1 << WDCE) | (1 << WDE);   // ウォッチドッグ変更許可(WDCEは4サイクルで自動リセット)
  // set new watchdog timeout value
  WDTCSR = bb;                          // 制御レジスタを設定
  WDTCSR |= _BV(WDIE);
}
 
ISR(WDT_vect) {                         // WDTがタイムアップした時に実行される処理
  wdt_cycle++;                      // 必要ならコメントアウトを外す
/*
  Serial.print("wdt_cycle = ");
  Serial.println(wdt_cycle);
*/
}
 
void sw_trig() {
  if(digitalRead(dsw) == LOW) {
    lcd.display();
  } else {
    lcd.noDisplay();
  }
  if(digitalRead(bsw) == LOW) {
    lcd.setBacklight(HIGH);
  } else {
    lcd.setBacklight(LOW);
  }
}
 
void clockDisp() {
  myRTC.updateTime();
  lcd.clear();
  lcd.print(myRTC.year);
  lcd.print("/");
  if(myRTC.month < 10) lcd.print("0");
  lcd.print(myRTC.month);
  lcd.print("/");
  if(myRTC.dayofmonth < 10) lcd.print("0");
  lcd.print(myRTC.dayofmonth);
  lcd.print("(");
  lcd.print(daysOfTheWeek[myRTC.dayofweek]);
  lcd.print(")");
 
  lcd.noBlink();
  lcd.setCursor(0,1);
  lcd.print("Time: ");
  if(myRTC.hours < 10) lcd.print("0");
  lcd.print(myRTC.hours);
  lcd.print(":");
  if(myRTC.minutes < 10) lcd.print("0");
  lcd.print(myRTC.minutes);
/*
    lcd.print(":");
    if(myRTC.seconds < 10) lcd.print("0");
    lcd.print(myRTC.seconds);
    delay(1000);
*/
}

 ライブラリには、次のものを使わせて頂きました。

 スケッチのスリープと復帰部分に関しては、ArduinoのCPUをスリープさせて消費電流を減らす関数 delayWDT2をそのまま使わせて頂きました。

 秒表示はしない前提で1分ごとに時計を更新表示させるべく、ウォッチドックタイマーの時間は、計算しやすい4秒としました。

 尚、delay()は使わなかったものの、ズレが生じる可能性は無視しました。

 2つのスイッチON/OFF状態用にsw_trig()、時計表示用にclockDisp()関数を作り、前者をloop()先頭、後者を初期表示の為、setup()に、また、WDT復帰時、かつ、1分ごとに表示のため、loop()内で実行させています。

 1分ごとの(4秒で復帰のウォッチドックタイマーを15回カウント)チェックをloop()内で行なうことで4秒ごとながら常時、スイッチ操作が効くという算段です。

 もちろん、操作を4秒にピタッと合わせる必要はなく、切り替え後のタイムラグとして現れます。

 MyRealTimeClockライブラリの場合、画面表示のONには、display()、OFFには、noDisplay()が、バックライトのON/OFFには、setBacklight(HIGH)/setBacklight(LOW)が用意されています。

 ちなみにsetBacklight()の引数には、0-255の値を入れることを想定しているようで255/0でも良いのですが、途中の値には、あまり意味がなさそうなのでHIGH/LOWで良いかと。

 ところでRTCモジュールにボタン電池を入れ、日付時刻を設定後、アップロード、更に日付時刻設定行をコメントアウト後、改めてアップロードしておかないと電源を入れるたび、スケッチ上の設定時の日付時刻から開始されてしまうので要注意です。

電池駆動検証

 2019/04/09 21:30〜 使用済み単3アルカリ電池x4(電圧5.55V)、液晶表示・バックライト共にONで使用開始。

 2019/04/14 21:30 使用済み単3アルカリ電池x4(電圧4.15V)、バックライトは明るいものの、液晶表示は、微かになり始めたので終了。

 5日とは、意外なほど短かったですね...ただ、電池電圧4.54V、LCD、DS1307、スイッチ部で残電圧3.1〜3.3V程度、もっといけそうなもんですし、鳥よけは電池残圧2V程度までで1ヶ月ほど持つんですが...、なぜ...。

 鳥よけは外部割り込み、この時計は4秒毎のWDTという違いによるのか、そもそも電池電圧4V台で随所で3V前半まで電圧降下、バックライトはともかく、そもそもLCDの入力電圧は5Vなんでしょうし、それだと不足ということなんでしょうね...。

 となるとICチップATMega328Pで実装してみるか、USB充電器で運用ですかね...。

備考

 ウォッチドックタイマーは最大8秒まで対応で8秒設定が最も省電力、今回は4秒なので最大の効果は発揮できないのでしょうが、どれくらいのものなんでしょう...。

 電流も0.01A以上を計測できるUSB電圧電流計だと比較どころか、常時、バックライトOFFで0.00A、ONで0.01Aという結果しか得ることができませんでした。

 ちなみにDS1302に使ったボタン電池も使用済みで残電圧2.8Vだったものを使っていますが、時刻保持もしてくれますし、機能はしており、検証でもこれを入れたままにしてあります。

[2019/04/14]

 単3エネループx4本で丸5日でした。

ケーシングしてみたArduino/RTC DS1302/LCD 1602時計
[2019/04/27]

 ユニバーサル基板にはんだ付け、表示、バックライトのON/OFFには、トグルスイッチを使い、100均セリアのトレカケースに入れてみました。

 LCDの配線が微妙に短いこともあり、ボルト止めするか否かは、思案中...。

 今更ながら、[Time:]なんて要らないですし、37センサーキット温湿度計DHT11の他に3つも入っていて余ってる温度計モジュールを入れるのもありか...収まらないか...、モジュールだと。

ケーシングしてみたArduino/RTC DS1302/LCD 1602時計の裏面

 配線は、盛りはんだしたり、新品もありますが、今回は、結構たまってる芯抜けしたりしたジャンパワイヤなどを使いました。

 今回使ったArduino Nanoボードは、ユニバーサル基板にメスのピンヘッダをハンダ付けして挿しました。

 尚、ユニバーサル基板は、そのままでは入らなかったので一辺だけ端っこをカッターで筋を入れてからラジオペンチで折り(割り)ました。

 ちなみに電子工作を初めて2年ちょい、ブレッドボード版を以て完成としたものは、そこそこありますが、ユニバーサル基板は、数カ月前、自作スマートスピーカー用にラズパイboot/reboot/shutdownボタンで使ったのが初めて、これが2つめです。

 ケースの底、内側には、基板のクッション代わりというか、配線外れ防止、底面密着回避の為にグルーガンで要所にグルーを盛るかしておくのも良いかなと。

 何度か電源を入れ直したりすると曜日が飛び、再アップしないと表示されなくなったりするのは、DS1307のご愛嬌(バグ)ってことでしょうか、Arduino公式サイトにも書いてあった通り、DS1302/DS1307ではなく、やっぱり、DS3231にしておく方が賢明そうです。

[2020/07/17]
温度計追加/LCD 1602をボルト留めしたArduino時計

 まだ残っている37センサーキットのセンサーを実用品に使い切ってみようかと手始めにESP32/TFT液晶 温湿度計付き時計BME280と差し替えてから最終的にどこにやったのか覚えていない(壊したかもしれない)DHT11を除く各種温度センサー3種の何れかを実用品に使ってみようと思うに至り、結果、サーミスタと半固定抵抗が載ったデジタル温度計を、この時計に組み込むことにしました...が、これは温度計としては使えない模様...

 既存配線済みのユニバーサルボードに追加でArduinoのA0-温度計モジュールのA0-カーボン抵抗10kΩ-VCCライン、温度計モジュールのVCC、GNDを、基板上のVCC、GNDラインにそれぞれに配線、ハンダ付け、温度計モジュール搭載のポテンショメータ(半固定抵抗)で温度を合わせるべく、良き位置に設定。

 サーミスタ部だけ露出しようかとも思いますが、とりあえず、温度センサーごと外出しにしています。

 LCDの固定については、あれからすぐ手持ちの銅製組ネジ・ナットセットで固定したのですが、出っ張り過ぎてしまって、ちょっと不恰好だったこともあり、先日、六角ボルト&ナットセットを買ったのでM3のボルトとナットに変更したら、それっぽくなりました。

視線に合わせブルタックで傾斜を付けた温度計付きArduino時計

 また、視認性を上げるべく、ケースに傾斜を付けるため、汚れず、傷つかず、何度でも練って使えるブルタックでデスク奥の端に斜めに固定、2ヶ月ほどは経っており、今回の作業の為に一度とりましたが、その体勢に変化はなく、ばっちりくっついてました。

 改めてブルタックで固定、写真ではわかりにくいものの、効果抜群で椅子に座った状態で視線をやると、とても鮮明に、よく見えます。

 ちなみに温度センサーもケース表面にブルタックでペタッとくっつけてます。

#include <LiquidCrystal_PCF8574.h>
#include <MyRealTimeClock.h>
#include <avr/sleep.h>                  // スリープライブラリ
#include <avr/wdt.h>                    // ウォッチドッグタイマー ライブラリ
 
LiquidCrystal_PCF8574 lcd(0x27); // lcd1602 yellow black
//LiquidCrystal_PCF8574 lcd(0x3F); // lcd2004 yellow black
 
MyRealTimeClock myRTC(6, 7, 8);
 
char daysOfTheWeek[7][12] = {"Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat"};
 
const int dsw = 4; // Display ON/OFF Switch
const int bsw = 5; // Backlight ON/OFF Switch
 
volatile int wdt_cycle = 0;           // 必要ならコメントアウトを削除
// 0=16ms, 1=32ms, 2=64ms, 3=128ms, 4=250ms, 5=500ms
// 6=1sec, 7=2sec, 8=4sec, 9=8sec
int wdt_time_num = 8;
// 60sec/4sec=15
int const_num = 15;
 
int ThermistorPin = A0;
int Vo;
float R1 = 10000; // value of R1 on board
float logR2, R2, T;
float c1 = 0.001129148, c2 = 0.000234125, c3 = 0.0000000876741; //steinhart-hart coeficients for thermistor
 
void setup() {
  Serial.begin(9600);
  pinMode(dsw, INPUT_PULLUP);
  pinMode(bsw, INPUT_PULLUP);
// 第4引数dayofweekは、sun=0,mon=1...
//  myRTC.setDS1302Time(00, 58, 17, 5 , 17, 7, 2020);
  lcd.begin(16, 2);
  lcd.print("DS1302 Clock");
  Serial.println("DS1302 Clock");
  lcd.setCursor(0,1);
  lcd.print("Start ...");
  Serial.println("Start ...");
  delay(2000);
  clock_temp_Disp();
}
 
void loop() {
  sw_trig();
//Serial.println(digitalRead(dsw));
  // delayWDT2(8):4sec*15=60sec
  if (wdt_cycle == const_num) {
    clock_temp_Disp();
    wdt_cycle = 0;
  }
  delayWDT2(wdt_time_num);
}
 
void delayWDT2(unsigned long t) {       // パワーダウンモードでdelayを実行
  Serial.flush();                       // シリアルバッファが空になるまで待つ
  delayWDT_setup(t);                    // ウォッチドッグタイマー割り込み条件設定
 
  // ADCを停止(消費電流 147→27μA)
  ADCSRA &= ~(1 << ADEN);
 
  set_sleep_mode(SLEEP_MODE_PWR_DOWN);  // パワーダウンモード指定
  sleep_enable();
 
  // BODを停止(消費電流 27→6.5μA)
  MCUCR |= (1 << BODSE) | (1 << BODS);   // MCUCRのBODSとBODSEに1をセット
  MCUCR = (MCUCR & ~(1 << BODSE)) | (1 << BODS);  // すぐに(4クロック以内)BODSSEを0, BODSを1に設定
 
  asm("sleep");                         // 3クロック以内にスリープ sleep_mode();では間に合わなかった
 
  sleep_disable();                      // WDTがタイムアップでここから動作再開
  ADCSRA |= (1 << ADEN);                // ADCの電源をON(BODはハードウエアで自動再開される)
}
 
void delayWDT_setup(unsigned int ii) {  // ウォッチドッグタイマーをセット。
  // 引数はWDTCSRにセットするWDP0-WDP3の値。設定値と動作時間は概略下記
  // 0=16ms, 1=32ms, 2=64ms, 3=128ms, 4=250ms, 5=500ms
  // 6=1sec, 7=2sec, 8=4sec, 9=8sec
  byte bb;
  if (ii > 9 ) {                        // 変な値を排除
    ii = 9;
  }
  bb = ii & 7;                          // 下位3ビットをbbに
  if (ii > 7) {                         // 7以上(7.8,9)なら
    bb |= (1 << 5);                     // bbの5ビット目(WDP3)を1にする
  }
  bb |= ( 1 << WDCE );
 
  MCUSR &= ~(1 << WDRF);                // MCU Status Reg. Watchdog Reset Flag ->0
  // start timed sequence
  WDTCSR |= (1 << WDCE) | (1 << WDE);   // ウォッチドッグ変更許可(WDCEは4サイクルで自動リセット)
  // set new watchdog timeout value
  WDTCSR = bb;                          // 制御レジスタを設定
  WDTCSR |= _BV(WDIE);
}
 
ISR(WDT_vect) {                         // WDTがタイムアップした時に実行される処理
  wdt_cycle++;                      // 必要ならコメントアウトを外す
/*
  Serial.print("wdt_cycle = ");
  Serial.println(wdt_cycle);
*/
}
 
void sw_trig() {
  if(digitalRead(dsw) == LOW) {
    lcd.display();
  } else {
    lcd.noDisplay();
  }
  if(digitalRead(bsw) == LOW) {
    lcd.setBacklight(HIGH);
  } else {
    lcd.setBacklight(LOW);
  }
}
 
void clock_temp_Disp() {
  myRTC.updateTime();
  lcd.clear();
  lcd.print(myRTC.year);
  lcd.print("/");
  if(myRTC.month < 10) lcd.print("0");
  lcd.print(myRTC.month);
  lcd.print("/");
  if(myRTC.dayofmonth < 10) lcd.print("0");
  lcd.print(myRTC.dayofmonth);
  lcd.print("(");
  lcd.print(daysOfTheWeek[myRTC.dayofweek]);
  lcd.print(")");
  Serial.print(myRTC.year);
  Serial.print("/");
  Serial.print(myRTC.month);
  Serial.print("/");
  Serial.print(myRTC.dayofmonth);
  Serial.print(" ");
  Serial.println(daysOfTheWeek[myRTC.dayofweek]);
 
  Vo = analogRead(ThermistorPin);
  R2 = R1 * (1023.0 / (float)Vo - 1.0); //calculate resistance on thermistor
  logR2 = log(R2);
  T = (1.0 / (c1 + c2*logR2 + c3*logR2*logR2*logR2)); // temperature in Kelvin
  T = T - 273.15; //convert Kelvin to Celcius
// T = (T * 9.0)/ 5.0 + 32.0; //convert Celcius to Farenheit
 
  lcd.noBlink();
  lcd.setCursor(0,1);
//  lcd.print("Time: ");
  if(myRTC.hours < 10) lcd.print("0");
  lcd.print(myRTC.hours);
  lcd.print(":");
  if(myRTC.minutes < 10) lcd.print("0");
  lcd.print(myRTC.minutes);
  lcd.print("  ");
  lcd.print(T);
  lcd.print(" C");
 
  Serial.print("Temperature: ");
  Serial.print(T);
  Serial.println(" C");
 
  Serial.print(myRTC.hours);
  Serial.print(":");
  Serial.println(myRTC.minutes);
/*
    lcd.print(":");
    if(myRTC.seconds < 10) lcd.print("0");
    lcd.print(myRTC.seconds);
    delay(1000);
*/
}

 スケッチは、37センサーの各種温度計のところにあるリンク先から拝借したものを取り入れさせて頂き、結果、こんな風にしました。

[2020/07/19]

 あれ?24℃以上にならない...。

 え?まさか、37センサーのサーミスタの載った4ピン温度センサーモジュールの半固定抵抗は、Max温度指定?それって何のため!?

 でも、そうだとするとデジタルピンが、その設定値に達したらON...というのは、辻褄が合いますけど...。

 もしかして、これって温度計じゃないの!?温度管理センサ!?あんまり情報がないみたいですが、どうもそうみたい

 付け替えないと...。

[2020/08/17]

 実は、2つ代替となるセンサーはあったのですが、その37センサーのサーミスタの載った3ピン温度センサーモジュール、DS18B20(DALLAS 18B20)の温度センサモジュール共になぜか、50度ほど高く表示されるようになり、なにかに使えるかもと思うものを集めた破損品ケース行きにした結果、妥当なセンサーが手元になく、放置していました。

 が、誤差が一定なら、その分、調整すればよいかと思い直し、例のなんと温度計としては使えなさ気な4ピンと同じアナログ信号をとればよい37センサーのサーミスタの載った3ピン温度センサーモジュールを復帰させ、使うことに。

 特定の温度計の精度にはなってしまうものの、他の温度計と比べて調整、電源投入直後は、50度程度高くなるのですが、これまた、なぜか、分単位で動かしている関係で表示が更新される1分後には、更に3度下げて上げてちょうどくらいになる...、というわけで5347度マイナスした値を表示させています。

 が、37センサーのサーミスタの載った3ピン温度センサーモジュールは、温度計用途に使うものではない模様。

ホーム前へ次へ