【Variables and Parameters / 変数とパラメータ】XSLT 2.0/XSL Transformations Version2.0/Extensible Stylesheet Language Transformations Version2.0

9.1 変数

<!-- カテゴリ：宣言 -->
<!-- カテゴリ：命令 -->
<xsl:variable
  name = qname
  select? = expression
  as? = sequence-type>
  <!-- Content: sequence-constructor -->
</xsl:variable>

xsl:variable 要素は、変数の名前を記述する name 属性を要求されています。 name 属性の値は、5.1 適格な名前で定義したようにQNameです。

xsl:variable 要素は、変数の要求タイプを記述する付加的な as 属性を持ちます。 as 属性の値は、[XPath 2.0]で定義したようにシーケンスタイプ^XPです。

[定義：  変数の値は、9.3 変数とパラメータの値で記述したように select 属性、または、含んだシーケンスコンストラクタの中で与えられる式を利用して算出されます。 この値は、変数の供給した値として参照されます。 ] もし、xsl:variable 要素が、 select 属性を持つ場合には、 シーケンスコンストラクタは、カラにしなければいけません。

もし、 as 属性が記述される場合には、変数の供給した値は、関数変換規則を利用して要求タイプに変換されます。

[ERR XTTE0570] もし、要求タイプに変換される事が出来ない変数の供給した値である場合には、それは、タイプエラーです。

もし、 as 属性が省略される場合には、 変数の供給した値は、直接利用され、変換は行われません。

9.2 パラメータ

<!-- カテゴリ：宣言 -->
<xsl:param
  name = qname
  select? = expression
  as? = sequence-type
  required? = "yes" | "no"
  tunnel? = "yes" | "no">
  <!-- Content: sequence-constructor -->
</xsl:param>

xsl:param 要素は、変換する為のパラメータを定義する為の xsl:stylesheetの子として、または、テンプレートにパラメータを定義する為に提供される xsl:template の子として利用される場合があり、 それは、テンプレートが、 xsl:call-template 、 xsl:apply-templates 、 xsl:apply-imports 、 または、 xsl:next-match を利用して実行される際に提供される場合があります； または、スタイルシート関数にパラメータを定義する為の xsl:function の子として、関数がXPath 式から呼ばれる際に提供される場合があります。

xsl:param 要素は、パラメータの名前を記述する name 属性を要求されています。 name 属性の値は、5.1 適格な名前で記述したように拡張されるQNameです。

[ERR XTSE0580] もし、テンプレートの2つのパラメータ、または、スタイルシート関数の2つのパラメータが、同じ名前を持つ場合には、それは、静的エラーです。

パラメータの供給した値は、呼んだものによって提供した値です。 もし、存在しない値が呼んだものによって提供された場合には、且つ、もし、パラメータが命令ではない場合には、 その提供した値は、9.3 変数とパラメータの値で記述したように select 属性、または、含んだシーケンスコンストラクタ内で与えられる式を利用して算出されます。 もし、その xsl:param 要素が、 select 属性を持つ場合には、 シーケンスコンストラクタは、カラにしなければいけません。

xsl:param 要素は、パラメータの要求タイプを記述する付加的な as 属性を持ちます。 as 属性の値は、[XPath 2.0]で定義したようにシーケンスタイプ^XPです。

もし、その as 属性が記述される場合には、 パラメータの供給した値は、関数変換規則を利用して要求タイプに変換されます。

[ERR XTTE0590] もし、その要求タイプへのパラメータの供給した値の変換が、失敗する場合には、それは、タイプエラーです。

もし、その as 属性が省略される場合には、パラメータの供給した値は、直接利用され、存在しない変換が行われます。

付加的な required 属性は、命令であるパラメータを示すために利用される場合があります。 この属性は、スタイルシートパラメータとテンプレートパラメータにおいて記述される場合があります。； 関数パラメータは常に命令の為に記述されてはいけません。 もし、それが、関数パラメータである、または、 もし、 required 属性が存在し、且つ、値 yes を持つ場合には、パラメータは命令です。 その他の場合には、パラメータはオプションです。 もし、パラメータが、命令である場合には、その時は xsl:param 要素は、カラにしなければいけませんが、 select 属性を持ってはいけません。

[ERR XTTE0600] もし、既定値が明示的に与える場合には、つまり、もし、 select 属性、または、カラではないシーケンスコンストラクタのいずれかである場合には、 もし、その既定値が、関数変換規則を利用して要求タイプに変換される事が出来ない場合には、それは、タイプエラーです。

もし、付加的なパラメータが、存在しない select 属性を持ち、更にカラのシーケンスコンストラクタを持つ場合、更には、 もし、存在しない as 属性がある場合には、パラメータの既定値は、ゼロの長さの文字列です。

[ERR XTDE0610] もし、付加的なパラメータが存在しない select 属性を持ち、且つ、カラのシーケンスコンストラクタを持ち、更に もし、 as 属性がある場合には、パラメータの既定値は、カラのシーケンスです。 もし、 カラのシーケンスが、 as 属性で定義した要求タイプの妥当なインスタンスではない場合に、 パラメータが要求したパラメータとして扱われる場合には、それがもし、パラメータにおいて存在しない値を提供する呼び出し元であれば、回復されない動的エラーです。

付加的な tunnel 属性は、トンネルパラメータであるパラメータを示すために利用される場合があります。 既定は no です；値 yes は、テンプレートパラメータにおいてのみ記述される場合があります。 トンネルパラメータは、10.1.2 トンネルパラメータの中で記述されます。

9.3 変数とパラメータの値

可変結合要素は、4つの異なる方法の中で変数の供給した値、または、 パラメータを記述する場合があります。

• もし、可変結合要素が、 select 属性を持つ場合には、 属性の値は、式と式を評価した結果である変数の供給した値にしなければいけません。 このケースでは、可変結合要素のコンテンツは、カラにしなければいけません。

• もし、可変結合要素が、カラのコンテンツを持ち、 select 属性、または、 as 属性のいずれでもないコンテンツを持つ場合、 変数の供給した値は、ゼロの長さの文字列です。 このように(以下の例の通りとなります)

  <xsl:variable name="x"/>
  

  (上記は以下と)同等

  <xsl:variable name="x" select="''"/>
  

• もし、可変結合要素が、存在しない select 属性を持ち、且つ、 カラの(1つ以上の子ノードを持つ)コンテンツを持つ場合には、そして更に存在しない as 属性を持つ場合には、 可変結合要素のコンテンツは、供給した値を記述します。 可変結合要素のコンテンツは、シーケンスコンストラクタです； 新しい文書は、シーケンスコンストラクタを評価した結果であるノードのシーケンスをその子として持っている文書ノードを伴って構築され、 そしてその時、5.7.1 複雑なコンテンツを構築するで与えた規則を適用します。 変数の値は、その時、1つのシーケンスが、この文書ノードを含んでいます。 より多くの情報は、9.4 暗黙の内に文書ノードを作成する参照。

• もし、可変結合要素が as 属性を持つものの、 select 属性が存在しない場合には、 供給した値は、可変結合要素の中に含んだ(カラが可能な) シーケンスコンストラクタ(参照先： 5.7 シーケンスコンストラクタ)を評価した結果であるシーケンスです。

これらの組み合わせは、以下のテーブルに要約されています。

[ERR XTSE0620] もし、可変結合要素が、 select 属性を持ち、更にカラではないコンテンツを持つ場合には、それは、静的エラーです。

<xsl:variable name="i" as="xs:integer*" select="1 to 3"/>

<xsl:variable name="i" as="xs:integer" select="@size"/>

<xsl:variable name="z"/>

<xsl:variable name="doc"><c/></xsl:variable>

<xsl:variable name="seq" as="xs:integer*">
	<xsl:for-each select="1 to 3">
		<xsl:sequence select=".*2"/>
	</xsl:for-each>
</xsl:variable>

<xsl:variable name="attset" as="attribute()+">
	<xsl:attribute name="x">2</xsl:attribute>
	<xsl:attribute name="y">3</xsl:attribute>
	<xsl:attribute name="z">4</xsl:attribute>		
</xsl:variable>

<xsl:variable name="empty" as="empty-sequence()"/>

変数の実際の値は、上に記述したように as 属性の値によって決定される供給した値と要求タイプに依存します。

<xsl:variable name="n">2</xsl:variable>
...
<xsl:value-of select="td[$n]"/>

<xsl:variable name="n" select="2"/>
...
<xsl:value-of select="td[$n]"/>

<xsl:variable name="n">2</xsl:variable>
...
<xsl:value-of select="td[position()=$n]"/>

<xsl:variable name="n" as="xs:integer">2</xsl:variable>
...
<xsl:value-of select="td[$n]"/>

9.4 暗黙の内に文書ノードを作成する

文書ノードは、カラでないコンテンツを持ち、存在しない as 属性を持つ xsl:variable 、 xsl:param 、または、 xsl:with-param 要素を評価する際に暗黙のうちに生成されます。 この要素は、可変結合要素として参照されます。 変数の値は、一時的なツリーの単独のノード、文書ノードです。. 文書ノードの内容は、5.7.1 複雑なコンテンツを構築するで記述したように可変結合要素の中に含んだシーケンスコンストラクタを評価した結果から形成されます。

<xsl:variable name="tree">
	<a/>
</xsl:variable>

<xsl:variable name="tree" as="document-node()">
	<xsl:document validation="preserve">
		<a/>
	</xsl:document>	
</xsl:variable>

文書ノードの基準URIは、スタイルシートにある要素を結びつけている変数の基準URIから取得されます。(参照：[データモデル]にあるセクション 5.2 base-uri Accessor^DM)

文書レベル妥当性検証は行われません(それが意味するところは、例えば、一意であるID値である事のチェックが存在しないという事です)。 しかしながら、新しいツリーにあるノード上のタイプ注釈は、変更されずにコピーされます。

文書ノードの document-uri と unparsed-entities プロパティは、カラに設定されます。

一時的なツリーは、いくつかのソース文書と同じ方法で確実な処理を可能にします。 例えば、そのノードは、 path 式を利用してアクセスされ、そして、それらは、 xsl:apply-templates と xsl:for-eachのような命令を利用して処理される事が可能です。 また、 key と id^FO 関数は、 文書ノードでルートとした一時的なツリーにあるノードを見つける為に利用される事ができ、 提供したまさにその時に関数が呼ばれる場合には、文脈アイテムは、一時的なツリーにあるノードです。

<xsl:stylesheet
	version="2.0"
	xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:import href="phase1.xsl"/>
<xsl:import href="phase2.xsl"/>
<xsl:variable name="intermediate">
	<xsl:apply-templates select="/" mode="phase1"/>
</xsl:variable>
<xsl:template match="/">
	<xsl:apply-templates select="$intermediate" mode="phase2"/>
</xsl:template>
</xsl:stylesheet>