【Callable Components / 呼び出し可能なコンポーネント】XSLT 2.0/XSL Transformations Version2.0/Extensible Stylesheet Language Transformations Version2.0

10.1 名前付きテンプレート

<!-- カテゴリ： 命令 -->
<xsl:call-template
  name = qname>
  <!-- Content: xsl:with-param* -->
</xsl:call-template>

[定義：  テンプレートは名前によって行使される事ができます。 name 属性を伴うxsl:template 要素は、名前付きテンプレートを定義します。 ] name 属性の値は、5.1 適格な名前で記述したように拡張されるQNameです。 もし、xsl:template 要素が、 name 属性を持つ場合には、それは、必要はありませんが、 match 属性も持つ場合があります。 xsl:call-template 命令は、名前によってテンプレートを実行します； それは、行使されるテンプレートを識別する name 属性を要求しています。 xsl:apply-templates 、 xsl:call-template 命令とは違い、 focus／フォーカスを変更しません。

xsl:template 要素上にある match 、 mode 、 priority 属性は、 テンプレートが、xsl:call-template 命令によって実行される際には、存在しない効果を持ちます。 とてもよく似た xsl:template 要素上にある name 属性は、 テンプレートが、 xsl:apply-templates 命令によって実行される際には、存在しない効果を持ちます。

[ERR XTSE0650] もし、スタイルシートにあるいくつかの xsl:template の name 属性とマッチしない name 属性のある xsl:call-template 命令を含む場合には、 それは、静的エラーです。

[ERR XTSE0660] もし、スタイルシートが、同じ名前と同じ取り込み優先度を持つテンプレートを1つ以上含む場合には、 それが、同じ名前とより高い取り込み優先度を持つテンプレートもまた含まない限り(含んでいる場合を除き)、 それは、静的エラーです。

xsl:call-template 命令における目標テンプレートは、 xsl:call-template 命令の name 属性とマッチする name 属性のあるテンプレートと この名前を伴ういくつかの他のテンプレートよりも、より高い取り込み優先度を持ちます。 xsl:call-template 命令の評価結果は、 その目標テンプレートの中で含んだシーケンスコンストラクタ (参照先： 5.7 シーケンスコンストラクタ) を評価する事によって生成したシーケンスです。

<xsl:template name="numbered-block">
	<xsl:param name="format">1. 
</xsl:param>
	<fo:block>
		<xsl:number format="{$format}"/>
		<xsl:apply-templates/>
	</fo:block>
</xsl:template>
<xsl:template match="ol//ol/li">
	<xsl:call-template name="numbered-block">
		<xsl:with-param name="format">a. 
</xsl:with-param>
	</xsl:call-template>
</xsl:template>

<xsl:template match="equation">
	<xsl:param name="equation-format" select="'(1)'" tunnel="yes"/>
	<xsl:number level="any" format="{$equation-format}"/>
</xsl:template>

<xsl:template match="appendix">
	...
	<xsl:apply-templates>
		<xsl:with-param name="equation-format" select="'[i]'" tunnel="yes"/>
	</xsl:apply-templates>
	...
</xsl:template>

10.2 名前付き属性セット

<!-- カテゴリ：宣言 -->
<xsl:attribute-set
  name = qname
  use-attribute-sets? = qnames>
  <!-- Content: xsl:attribute* -->
</xsl:attribute-set>

[定義：  xsl:attribute-set 要素は、異なる要素の構築を繰り返し利用される事が可能な属性定義のコレクションである名前付き属性セットを定義します。 ]

要求した name 属性は、属性セットの名前を記述します。 name 属性の値は、5.1 適格な名前で記述した拡張されるQNameです。 xsl:attribute-set 要素の内容は、そのセットにある属性を生成する為に評価されるゼロ以上の xsl:attribute 命令で構成します。

属性セットを評価した結果は、属性ノードのシーケンスです。 同じ属性セット評価は、他方で属性セットは、パラメータを持つ事をせず、それは、式、または、文脈の評価に依存する値のある命令を含む場合があるので1回以上異なる結果を生成する事ができます。

属性セットは、 xsl:element 上にある use-attribute-sets 属性、 または、 xsl:copy 命令を記述する事によって、または、 リテラル結果要素上にある xsl:use-attribute-sets 属性を記述する事によって利用されます。 属性セットは、 xsl:attribute-set 要素それ自身にある use-attribute-sets 属性を利用する事によって他の属性セットの用語の中に定義される場合があります。 [xsl:]use-attribute-sets 属性の値は、属性セットの名前のホワイトスペースで区切られたリストケースごとにあります。 それぞれの名前は、5.1 適格な名前で記述したように拡張さるQNameです。

use-attribute-sets 属性を記述することは、 use-attribute-sets 属性で記述される属性セットの名前において同じ命令にある [xsl:]use-attribute-sets 属性を伴う命令の内容の始まるところに名前付き属性セットごとに各属性における xsl:attribute 命令を追加する事と広義においては(同じではないものの)同様です。

より公式には、 xsl:use-attribute-sets 属性は、次に続く再帰的なアルゴリズム、または、同じ結果を生成するいくつかのアルゴリズムを利用して拡張されます：

• 属性の値は、QNameのリストとしてトークン分割されます。

• リスト中の各QNameは、次に続くように命令の中で処理されます：

  • QNameは、スタイルシートにある xsl:attribute-set 宣言内の1つ以上の name 属性とマッチしなければならない。

  • 名前がマッチする各 xsl:attribute-set 宣言は、次に続くように処理される。 2つのこのような宣言が、異なる取り込み優先度を持つ場合、 取り込み優先度の低い方から最初に処理される。 2つの宣言が、同じ取り込み優先度である場合、それらは、宣言指定の中で処理される。

    • もし、 xsl:attribute-set 宣言が、 use-attribute-sets 属性を持つ場合、 属性は、このアルゴリズムを再帰的に適用する事によって拡張される。

    • もし、 xsl:attribute-set 宣言が、1つ以上の xsl:attribute 命令を含む場合には、 これらの命令は、属性ノードのシーケンスを生成する為に評価される。 これらの属性ノードは、結果シーケンスに付加される。 (次に続く規則シーケンスコンストラクタ評価については、5.7 シーケンスコンストラクタ参照)

xsl:attribute 命令は、要素を評価する事において利用されるのと同じfocus／フォーカスを利用して評価されます。 要素は、アルゴリズムに初期入力を形成する [xsl:]use-attribute-sets 属性の親です。 しかしながら、評価における静的文脈は、スタイルシートにある xsl:attribute 命令の位置に依存します： このように、単に xsl:attribute 命令内で宣言したローカル変数とグローバル変数は、可視です。

xsl:use-attribute-sets を拡張する事によって生成される属性ノードのセットは、同じ名前を持ついくつかの属性を含む場合があります。 属性が、要素ノードに追加される際には、単に複数ある中の1つが、効果を受け取ります。

各命令における方法は、関連する命令における仕様で記述される [xsl:]use-attribute-sets 属性を拡張した結果を利用します:11.1 リテラル結果要素、11.2 [ xsl:element ]を利用して要素ノードを生成する 、11.9 ノードをコピーする参照。

[ERR XTSE0710] もし、xsl:copy 、 xsl:element 、または、 xsl:attribute-set 要素の use-attribute-sets 属性の値、または、リテラル結果要素の xsl:use-attribute-sets 属性の値が、 QNamesのホワイトスペース区切りのシーケンスでない場合、 または、 もし、スタイルシートにあるいくつかの xsl:attribute-set 宣言の name 属性とマッチしないQNameを含む場合には、 それは、静的エラーです。

[ERR XTSE0720] もし、直接 xsl:attribute-set 要素、または、間接的に use-attribute-sets 属性に含んだ名前経由でそれ自身を参照する場合には、それは、静的エラーです。

属性セットを拡張する事によって生成された各属性ノードは、属性ノードを生成した xsl:attribute 命令における規則によって決められるタイプ注釈を持ちます: 11.3.1 構築した属性ノードにおけるタイプ注釈を設定する参照。 これらのタイプ注釈は、属性が利用される中において要素を創出する命令における規則によって保存、除去、または、置換される場合があります。

属性セットは、次に続くように利用されます：

• xsl:copy と xsl:element 命令は、 use-attribute-sets 属性を持ちます。 この属性を評価する事によって生成した属性ノードのシーケンスは、命令の中に含んだシーケンスコンストラクタをシーケンスの先頭に追加されます。

• リテラル結果要素は、 xsl:element と xsl:copy の use-attribute-sets 属性と同じ方法で評価される xsl:use-attribute-sets 属性を許容します。 この属性を評価する事によって生成した属性ノードのシーケンスは、リテラル結果要素を伴って含んだシーケンスコンストラクタを評価する事によって生成したシーケンスを先頭に追加されて戻る中で、リテラル結果要素の属性を評価する事によって生成した属性ノードのシーケンスを先頭に追加されます。

<xsl:template match="chapter/heading">
	<fo:block font-stretch="condensed" xsl:use-attribute-sets="title-style">
		<xsl:apply-templates/>
	</fo:block>
</xsl:template>
<xsl:attribute-set name="title-style">
	<xsl:attribute name="font-size">12pt</xsl:attribute>
	<xsl:attribute name="font-weight">bold</xsl:attribute>
</xsl:attribute-set>

<xsl:attribute-set name="base-style">
	<xsl:attribute name="font-family">Univers</xsl:attribute>
	<xsl:attribute name="font-size">10pt</xsl:attribute>
	<xsl:attribute name="font-style">normal</xsl:attribute>
	<xsl:attribute name="font-weight">normal</xsl:attribute>
</xsl:attribute-set>
<xsl:template match="o">
	<fo:block xsl:use-attribute-sets="base-style"
			font-size="12pt"
			font-style="italic">
		<xsl:attribute name="font-size">14pt</xsl:attribute>
		<xsl:attribute name="font-weight">bold</xsl:attribute>
		<xsl:apply-templates/>
	</fo:block>
</xsl:template>

<fo:block font-family="Univers"
		font-size="14pt"
		font-style="italic"
		font-weight="bold">
...
</fo:block>

10.3 スタイルシート 関数

[定義：  xsl:function 宣言は、スタイルシートにあるいくつかのXPath 式から呼ばれる事が可能な名前、パラメータ、スタイルシート関数の手法を宣言します。 ]

<!-- カテゴリ：宣言 -->
<xsl:function
  name = qname
  as? = sequence-type
  override? = "yes" | "no">
  <!-- Content: (xsl:param*, sequence-constructor) -->
</xsl:function>

xsl:function 宣言は、スタイルシートの中で利用した(パターンにある述語の中で利用したXPath式を含む)いくつかのXPath 式から呼ばれる事が可能なスタイルシート関数を定義します。 name 属性は、関数の名前を記述します。 name 属性の値は、5.1 適格な名前で記述したように拡張されるQNameです。

xsl:function 宣言は、スタイルシートモジュールにあるトップレベル要素としてのみ現れる事が可能です。

[ERR XTSE0740] スタイルシート関数は、既定関数名前空間にある関数を伴ういくつかの衝突のリスクを排除する為に前置詞付きの名前を持っていなければいけません。 もし、名前が存在しない前置詞を持つ場合には、それは、静的エラーです。

xsl:function 要素の内容は、関数によって返される為の値を定義するシーケンスコンストラクタによって次に続く関数の公式な引数を記述するゼロ以上の xsl:param 要素で構成します。

[定義：  スタイルシート関数のarity(関数における引数の数)は、関数定義にある xsl:param 要素の数です。 ] 付加的な引数は、許容されません。

[ERR XTSE0760] スタイルシート関数呼び出しにおける引数は、全て記述されなければならないので、 xsl:function 要素内にある xsl:param 要素は、既定値を記述してはいけません： これが意味するところは、それらは、カラにしなければならず、 select 属性を持つ必要はないという事です。

スタイルシート関数は、(以下でない限り)スタイルシートの中で利用した全てのXPath式において、 静的文脈の スコープ内関数 に含まれます。

• 同じ名前とarityとより高い取り込み優先度を持つその他のスタイルシート関数、または、

• override 属性が、値 no を持ち、スコープ内関数にある同じ名前とarityを伴う関数が既に存在する

付加的な override 属性は、もし、手法によって、または、 [implementation-defined] メカニズムを利用して静的文脈の中で利用可能となった関数として同じ名前とarityを持つ場合には、何が起きるかを定義します。 もし、 override 属性が、値 yes を持つ場合には、この関数は優先して利用されます； もし、それが、値 no を持つ場合には、他の関数が優先して利用されます。 既定値は、 yes です。

[ERR XTSE0770] 同じ拡張QNameと arity 、そしてより高い取り込み優先度を持つその他の関数がない限り、スタイルシートにおいて2つ以上の 同じ拡張QName、 同じarity、 、同じ取り込み優先度を伴う関数を含む事は、静的エラーです。

XPathで定義したように、関数は、関数呼び出しにある引数の名前と数がマッチする名前とarityのある関数において静的文脈のスコープ内関数の中で探す事によって識別される関数呼び出しの結果として実行されます。

付加的な as 属性は、関数の結果の要求タイプを表示します。 as 属性の値は、[XPath 2.0]で定義したようにシーケンスタイプ^XPです。

[ERR XTTE0780] もし、 as 属性が記述される場合には、 シーケンスコンストラクタ(参照：5.7 シーケンスコンストラクタ)によって評価した結果は、 関数変換規則を利用して要求タイプに変換されます。 もし、この変換が失敗する場合には、それは、タイプエラーです。 もし、 as 属性が省略される場合には、算出した結果は、提供した時に利用され、存在しない変換が行われます。

もし、スタイルシート関数が、固有の拡張QNameを伴って定義されている場合には、 この同じ拡張QNameに拡張する語彙的なQNameである引数を伴い、呼ばれた際に「true」を返すであろう function-available を呼びます。

xsl:param 要素は、関数に公式な引数を定義します。 これらは、局地的に解釈されます。 関数が、XPath 式にある関数呼び出し(ファンクションコール)を利用して呼ばれた際には、提供した最初の引数は、 最初の xsl:param 要素に割り当てられ、次に提供した引数は、 xsl:param 要素に2番目に割り当てられ。。。つづく。

xsl:param 要素の as 属性は、パラメータの要求タイプを定義します。 xsl:param 要素ごとによって要求したタイプを関数呼び出しの中で提供した実際の引数の値に変換する事については、[XPath 2.0]で定義されます。 適用する規則は、XPath 1.0互換性モードが、 false に設定される場合には、それらのケースです。

[ERR XTTE0790] もし、スタイルシート関数へのパラメータの値が、要求タイプに変換できない場合には、タイプエラー がシグナル出力されます。

もし、 as 属性が省略される場合には、存在しない変換がおこなわれ、いくつかの値が許容されます。

スタイルシート関数の本体内では、focus／フォーカスは、初期の未定義です； これが意味するところは、いくつかの文脈アイテム、文脈位置、または、文脈サイズを参照する為の試みは、回復されない動的エラーであるという事です。 [XPDY0002]

関数呼び出しが書かれる場合には、その位置でスコープにあったローカル変数の値にアクセスする為のスタイルシート関数の本体内では、利用可能ではありません。 グローバル変数は、しかしながら、そのまま利用可能です。

<xsl:transform 
	xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
	xmlns:xs="http://www.w3.org/2001/XMLSchema"
	xmlns:str="http://example.com/namespace"
	version="2.0"
	exclude-result-prefixes="str">
<xsl:function name="str:reverse" as="xs:string">
	<xsl:param name="sentence" as="xs:string"/>
	<xsl:sequence	
		 select="if (contains($sentence, ' '))
			 then concat(str:reverse(substring-after($sentence、 ' ')),
			 ' ',
			 substring-before($sentence, ' '))
			 else $sentence"/>
</xsl:function>
<xsl:template match="/">
<output>
	<xsl:value-of select="str:reverse('DOG BITES MAN')"/>
</output>
</xsl:template>
</xsl:transform>

<xsl:function name="str:reverse" as="xs:string">
	<xsl:param name="sentence" as="xs:string"/>
	<xsl:choose>
		<xsl:when test="contains($sentence, ' ')">	
			<xsl:sequence select="concat(str:reverse(substring-after($sentence, ' ')),
				' ',
				substring-before($sentence, ' '))"/>
		</xsl:when>
		<xsl:otherwise>
			<xsl:sequence select="$sentence"/>
		</xsl:otherwise>
	</xsl:choose>
</xsl:function>

<xsl:function name="num:roman" as="xs:string">
	<xsl:param name="value" as="xs:integer"/>
	<xsl:number value="$value" format="i"/>
</xsl:function>